配管サイズや本数、出方向を考慮してプルボックス寸法を決めるのは、現場でも設計でも意外と手間がかかる作業。
「もっと簡単に、ミスなく選定できたら…」そんな声に応えるべく、Excelで自動計算できるプルボックス選定ツールを作りました。
本記事では、線種・直線・直角・電線管を選択して本数を入力するだけで、最適なプルボックスサイズが自動計算できる仕組み を紹介します。計算ミスを防ぎ、スムーズに作業が進められるので、計装・電気工事の初心者にもおすすめ！
「難しい計算はちょっと…」という方も、この方法ならすぐに実践できますよ！早速、Excelでのプルボックス選定の流れを見ていきましょう。
今回も、オンライン版のExcelを使用して作成します。
プルボックスの選定方法いついて詳しく知りたい方は、こちらの記事をご覧ください。
ダウンロードページへ進む
会社のポリシーにより、外部ファイルのダウンロードが制限されている場合は、以下の手順でご対応ください。
各セルに必要な関数を手動で入力することで、同様の選定結果を得ることができます。
本計算方法は、建築設備設計基準に準拠しています。
準備 -それぞれの役割に応じたシートを用意しましょう。-
今回は
- 入力
- データ
- 計算シート
の3シート構成で設計していきます。
【データ】シート
はじめに、配管サイズや本数などの情報を入力するためのシートを準備します。
- A列：線種
- B列：配管の方向（直線・直角）
- C列：電線管の種類（今回はE管とG管）
- D列：電線管外径
- E列：パターン（線種）
- F列：パターン（方向）
- G列：計算式
- H3:L12 プルボックスの高さ選定用の表を用意します。
- H列：G管サイズ
- I列：E管サイズ
- J列：1段配列の高さ
- K列：2段配列の高さ
- L列：3段配列の高さ
【入力フォーム】シート
入力ミスを防ぐために、Excelの「入力規則」を使ってデータ入力シートを作成していきます。
A1セル：線種
A2セル
- 入力規則の設定手順
① セルを選択 → ②「データ」タブ → ③「データの入力規則」 → ④「リスト」選択 → ⑤データシートの A2:A3 を選択 - メリット：入力ミス防止・選択式で初心者も安心・テンプレート化しやすい
B2・C2セルにも、A2と同じように「入力規則」を設定します。リストから選ぶ形式にすることで、入力ミスを防ぎ、テンプレートとしても使いやすくなります。
C2セルに入力後、セル右下のフィルハンドルをドラッグして、E11セルまで自動コピーします。これにより、同じ設定を一括で反映できます。
【計算シート】シートを作成
続いて、計算処理を行うための「計算用シート」を作成します。ここでは、入力されたデータをもとにプルボックス寸法を自動算出していきます。
A1セル：電線管（1段）
B1セル：電線管（2段）
C1セル：電線管（3段）
A2セル
=入力フォーム!C2
を入力し、C11セルまでコピーします。
D〜F列では、入力された配管情報をもとに、VLOOKUP関数で対応するサイズを自動取得します。これにより、計算シートとの連携がスムーズになります。
D2セル
=VLOOKUP(A2,データ!$C$2:$D$18,2,FALSE)
F列の計算式を、F11セルまでコピーすることで、複数行に一括反映できます。
A12セル
=COUNTIF(A2:A11,"<>0")
A12の計算式を、C12セルまでコピーします。
電線管の本数を確認します。
D12セル
=AGGREGATE(9,6,D2:D11)
D12の計算式を、F12セルまでコピーします。
電線管長の合計を計算します。
D13セル
=AGGREGATE(4,6,D2:D11)
D13の計算式を、F13セルまでコピーします。
電線管の最大径を表示します。
G11セル
=COUNTIF(D12:F12,"<>0")
電線管の段数を計算します。
G12セル
=MAX(D13:F13)
電線管径の最大合計を表示します。
G13セルにコピーします。
電線管の最大径を表示します。
計算式の視認性を高めるため、H列に数式を表示します。データシートの計算式をコピーし、H5セルに貼り付けています。
H3セル
=MATCH(1, (データ!E2:E5=入力フォーム!A2)*(データ!F2:F5=入力フォーム!B2), 0)
H2セル
=IFERROR(INDEX(データ!G2:G5, H3), "条件未選択")
この関数により、入力フォームで指定した【線種】と【直線・直角】に一致する計算式が表示されます。
まずは、【入力フォーム】シートの A2・B2 セルを選択してみましょう。条件に一致する計算式が自動で表示されます。
式の構造と意味
=MATCH(1, (データ!E2:E5=入力フォーム!A2)*(データ!F2:F5=入力フォーム!B2), 0)
目的
「データ」シートの E列と F列の両方が、「入力フォーム」シートの A2・B2セルと一致する最初の行番号（相対位置）を返す。
分解して解説
| 部分 | 意味 |
|---|---|
データ!E2:E5=入力フォーム!A2 | E列の各セルが A2 と一致するか（TRUE/FALSEの配列） |
データ!F2:F5=入力フォーム!B2 | F列の各セルが B2 と一致するか（TRUE/FALSEの配列） |
(...) * (...) | 両方一致した場合のみ TRUE（=1）になる（AND条件） |
MATCH(1, ..., 0) | 上記の配列の中で「1（TRUE）」が最初に出現する位置を返す |
続いて、赤枠で囲った計算式の部分を完成させていきます。
| I | J | K | L | M | N | O | P |
|---|---|---|---|---|---|---|---|
| =MATCH(G12,D12:F12,0) | （A） | （B） | |||||
| =$G$12 | =30*OFFSET($A$12,0,$J$4-1) | =30*2 | =SUM(I5:L5) | =G13*6 | =MAX(M5:N5) | =CEILING(O5,100) | |
| =$G$12 | =30*OFFSET($A$12,0,$J$4-1) | 30 | =G13*3 | =SUM(I6:L6) | =MAX(M6:N6) | =IF(M6<200,200,CEILING(O6,100)) | |
| =$G$12 | =30*OFFSET($A$12,0,$J$4-1) | =30*2 | =SUM(I7:L7) | =G13*8 | =MAX(M7:N7) | =CEILING(O7,100) | |
| =$G$12 | =30*OFFSET($A$12,0,$J$4-1) | 30 | =G13*3 | =SUM(I8:L8) | =MAX(M8:N8) | =CEILING(O8,100) | |
| 最大電線管径の合計 | 最大電線管径の段数 Σ(P＋30) | 追加定数 | 最大電線管径（3Pm） | 合計 （Ｉ：Ｌ） | 最大電線管径（6Pm）or（8Pm） | 最大値 （A）or（Ｂ） | 数値を「100単位」で切り上げ |
I2セル
=IFERROR(VLOOKUP(H2,H4:P8,9,FALSE),"0")
この式は、入力条件に基づいてP.BOXサイズを算出するための最終計算値です。
I11セル
=INDEX(データ!C:C, MATCH(G13, データ!D:D, 0))
電線管最大サイズを表示
N11セル
=VLOOKUP(I11,データ!I3:L12,G11+1,FALSE)
電線管（E）プルボックス高さ
O11セル
=VLOOKUP(I11,データ!H3:M12,G11+2,FALSE)
電線管（G）プルボックス高さ
P11セル
=AGGREGATE(4,6,N11:O11)
エラーを無視して最大値を取得
【入力フォーム】シート
G1セル値：計算式
G4セル値：サイズ（幅）
G5セル値：サイズ（高）
I4セル値：mm
I5セル値：mm
H2セル
=計算シート!H2
H4セル
=計算シート!I2
H5セル
=計算シート!P11
使用方法
- A2セル：『線種』（絶縁電線・ケーブル）を選択します。
- B2セル：『形状』（直線・直角）を選択します。
※三方向・四方向の場合は「直角」を選択してください。 - C列（2～11）：一段目の電線管を選択します。
- D列（2～11）：二段目の電線管を選択します。
- E列（2～11）：三段目の電線管を選択します。
- H4セル：条件に応じたプルボックスの「幅（サイズ）」が表示されます。
- H5セル：条件に応じたプルボックスの「高さ（サイズ）」が表示されます。